Предыдущая | Следущая

MovieClipLoader.onLoadInit

Доступность

Flash Player 7.

Синтаксис

listenerObject.onLoadInit = function([target_mc:MovieClip]) {
  // код
}

Параметры

listenerObject Объект-слушатель событий (listener), добавленный при помощи MovieClipLoader.addListener().

target_mc Клип, загруженный методом MovieClipLoader.loadClip(). Необязательный параметр.

Возвращает

Ничего.

Описание

Listener;вызывается когда комманды в первом фрейме загруженного клипа будут выполнены. После этого Вы можете устанавливать свойства, использовать методы или как-либо иначе управлять загруженным клипом.

Значение target_mc определяет клип, для кторого был применен вызов метода. Этим параметром удобно пользоваться при загрузке нескольких файлов с одним и тем же набором listener'ов. Этот необязательный параметр передается в код.

Пример

В клип image_mc загружается изображение. События onLoadInit и onLoadComplete используются для того, чтобы определить сколько времени заняла загрузка. Информация выводится в динамически созданном текстовом поле timer_txt.

this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
var mclListener:Object = new Object();
mclListener.onLoadStart = function(target_mc:MovieClip) {
  target_mc.startTimer = getTimer();
};
mclListener.onLoadComplete = function(target_mc:MovieClip) {
  target_mc.completeTimer = getTimer();
};
mclListener.onLoadInit = function(target_mc:MovieClip) {
  var timerMS:Number = target_mc.completeTimer-target_mc.startTimer;
  target_mc.createTextField("timer_txt", target_mc.getNextHighestDepth(), 0, target_mc._height, target_mc._width, 22);
  target_mc.timer_txt.text = "loaded in "+timerMS+" ms.";
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.macromedia.com/images/shared/product_boxes/112x112/box_studio_112x112.jpg", image_mc);

См. также

MovieClipLoader.onLoadStart

Посмотреть комментарии LiveDocs		Предыдущая | Следущая